Competency questions

1. Retrieve all the protocols with samples that belong to the Rodent order
   Makes use of external resources, federated query
2. Retrieve all the protocols with reagents of type Enzyme
   Makes use of external resources, federated query
3. Retrieve all the protocols with reagents of type Alcohol
   Makes use of external resources, federated query
4. Retrieve all the reagents and the web sites to buy them and all the different manufacturers registered for every reagent
5. Retrieve all the protocols with Fetal bovine serum (FBS) as a reagent
6. Retrieve the application of the protocol titled “Extraction of total RNA from fresh/frozen tissue (FT)”
7. Retrieve the procedure labels for the protocol titled “Extraction of total RNA from fresh/frozen tissue (FT)”
8. Retrieve the purpose of the protocol titled “Isolation of Lung Infiltrating Cell in Mice”
9. Retrieve all the instruments and reagents used in the protocol “Mouse Retinal Whole Mounts and Quantification of Vasculature Protocol”
10. Retrieve the protocols that use the reagents “Dulbecco’s modified eagle medium (DMEM)”, “Fetal bovine serum (FBS)” and “Phosphate buffered saline (PBS)”
11. Retrieve all the protocols that contain Mouse as a Sample
12. Retrieve all the protocols that use the software “ImageJ” and the corresponding homepage (http://rsb.info.nih.gov/ij/download.html).
13. Retrieve all the reagents manufactured by Sigma-Aldrich in protocol “Isolation of Lung Infiltrating Cell in Mice”
14. Retrieve all the diseases caused by the reagents in the protocol “Extraction of total RNA from fresh/frozen tissue (FT)”
    Makes use of external resources, federated query
15. Retrieve all the protocols with “Schizosaccharomyces pombe” in the list of samples
16. Retrieve the protocols that include 2 or more procedures
17. Retrieve the critical steps included in the protocol titled “[Bio101] Subcutaneous Injection of Tumor Cells”
18. Retrieve the advantages and limitations of the protocol titled “Defining transcribed regions using RNA-seq”
19. Retrieve the recipe list of the protocol titled “Defining transcribed regions using RNA-seq”
20. For the protocol titled “Defining transcribed regions using RNA-seq”, give me the steps that include cautions as alert messages and also retrieve the materials participating in such step
21. Retrieve the provenance of the protocol titled “Scratch Wound Healing Assay”
22. Retrieve the specimen names tested in the protocols titled “A simplified universal genomic DNA extraction protocol suitable for PCR” and “RNA Isolation from Synechocystis”
23. Retrieve the protocols and the list of reagents for documents authored by Yanling Chen
24. Retrieve the protocols authored by Cristian Olaya and Wilmer Cuellar using Cassava (NCBITAXON:3983) as a sample
25. Retrieve the common reagents across the protocols “[Bio101] Subcutaneous Injection of Tumor Cells” and “Scratch Wound Healing Assay”
26. Retrieve the protocols in which Bromophenol blue is used and tell me about the application of Bromophenol blue
27. Retrieve the protocols and the list of reagents for documents authored by Yoshimi Umemura
28. Retrieve the protocols authored by Yoshimi Umemura and Beata Dedicova using rice leaves as sample

1. Retrieve all the protocols with samples that belongs to the Rodent order

Makes use of external resources, federated query

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?title ?specimenName
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?specimens .
  ?specimens a sp:SpecimenList .
  ?specimens ro:has_part ?specimenNameUri.
  ?specimenNameUri rdf:value ?specimenName .
  ?specimen sp:hasName ?specimenNameUri.
  SERVICE <https://dbpedia.org/sparql>
  {
    ?externalUri dbo:order <http://dbpedia.org/resource/Rodent> .
    ?externalUri rdfs:comment ?dbpediaDesc .
    FILTER(lang(?dbpediaDesc) = 'en')
  }
  ?specimen owl:sameAs ?externalUri .
}

2. Retrieve all the protocols with reagents of type Enzyme

Makes use of external resources, federated query. If federated resources dont respond then this query will give an error msg.

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?title ?name ?desc
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri.
  ?reagent owl:sameAs ?externalUri .
  ?reagent sp:hasName ?reagentNameUri .
  ?reagentNameUri rdf:value ?name .
  SERVICE <https://dbpedia.org/sparql> {
    ?externalUri a dbo:Enzyme .
    ?externalUri rdfs:comment ?desc .
    FILTER(lang(?desc) = 'en')
  }
}

3. Retrieve all the protocols with reagents of type Alcohol

Makes use of external resources, federated query. If federated resources dont respond then this query will give an error msg.

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX yago: <http://dbpedia.org/class/yago/>

SELECT ?title ?name ?desc
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagent owl:sameAs ?externalUri .
  ?reagent sp:hasName ?reagentNameUri .
  ?reagentNameUri rdf:value ?name .
  SERVICE <https://dbpedia.org/sparql> {
    ?externalUri a yago:WikicatAlcohols .
    ?externalUri rdfs:comment ?desc .
    FILTER(lang(?desc) = 'en')
  }
}

4. Retrieve all the reagents along with the different web sites to buy them and all the different manufacturers registered for every reagent.

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX obi: <http://purl.obolibrary.org/obo/OBI_>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX CHEBI: <http://purl.obolibrary.org/obo/CHEBI_>

SELECT ?name
     (group_concat(?manufacturerName; separator=" , ") as ?manufacturers)
     (group_concat(?homepage; separator=" , ") as ?reagentHomepage)
WHERE {
  ?reagent a CHEBI:33893 .
  ?reagent sp:hasName ?nameUri .
  ?nameUri rdf:value ?name .
  ?reagent obi:0000304 ?manufacturer .
  ?manufacturer sp:hasName ?manufacturerNameUri .
  ?manufacturerNameUri rdf:value ?manufacturerName .
  ?reagent foaf:homepage ?homepage .
} GROUP BY ?name

5. Retrieve all the protocols with Fetal bovine serum (FBS) as a reagent

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>

SELECT ?title
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value "Fetal bovine serum (FBS)" .
}

6. Retrieve the application of the protocol titled “Extraction of total RNA from fresh/frozen tissue (FT)”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?protocolApplication
{
    ?protocol sp:hasTitle ?titleUri .
    ?titleUri rdf:value "Extraction of total RNA from fresh/frozen tissue (FT)" .
    ?protocol sp:hasApplication ?applicationUri .
    ?applicationUri rdf:value ?protocolApplication .
} 

7. Retrieve the procedure labels involved in the protocol titled “Extraction of total RNA from fresh/frozen tissue (FT)”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?procedureLabel
{
    ?experimentalProtocol sp:hasTitle ?titleUri .
    ?titleUri rdf:value "Extraction of total RNA from fresh/frozen tissue (FT)" .
    ?experimentalProtocolExecution sp:isDocumentedIn ?experimentalProtocol .
    ?experimentalProtocolExecution sp:hasProcedure ?procedure .
    ?procedure rdfs:label ?procedureLabel .
}

8. Retrieve the purpose of the protocol titled “Isolation of Lung Infiltrating Cell in Mice”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?protocolPurpose
{
    ?protocol sp:hasTitle ?titleUri .
    ?titleUri rdf:value "Isolation of Lung Infiltrating Cell in Mice" .
    ?protocol sp:hasPurpose ?purposeUri .
    ?purposeUri rdf:value ?protocolPurpose .
}

9. Retrieve all the instruments and reagents used in the protocol “Mouse Retinal Whole Mounts and Quantification of Vasculature Protocol”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>

SELECT (group_concat(distinct(?reagentName);separator=" | ") as ?protocolReagents)
       (group_concat(distinct(?equipmentName);separator=" | ") as ?protocolInstruments)
WHERE {
    ?protocol sp:hasTitle ?title_uri .
    ?title_uri rdf:value "Mouse Retinal Whole Mounts and Quantification of Vasculature Protocol" .
    ?protocol sp:hasExperimentalInput ?reagents .
    ?reagents a sp:ReagentList .
    ?reagents ro:has_part ?reagentNameUri .
    ?reagentNameUri rdf:value ?reagentName .
    ?protocol sp:hasExperimentalInput ?equipment .
    ?equipment a sp:EquipmentAndSuppliesList .
    ?equipment ro:has_part ?equipmentNameUri .
    ?equipmentNameUri rdf:value ?equipmentName .
} GROUP BY ?protocol

10. Retrieve the protocols that use the reagents “Dulbecco’s modified eagle medium (DMEM)”, “Fetal bovine serum (FBS)” and “Phosphate buffered saline (PBS)”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/prism:>

SELECT DISTINCT ?identifier ?title ?publicationName
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasIdentifier ?protocolIdentifier .
  ?protocolIdentifier rdf:value ?identifier .
  ?protocol sp:publishedIn ?publication .
  ?publication sp:hasName ?publicationNameUri .
  ?publicationNameUri rdf:value ?publicationName .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri1 .
  ?reagentNameUri1 rdf:value "Fetal bovine serum (FBS)" .
  ?reagents ro:has_part ?reagentNameUri2 .
  ?reagentNameUri2 rdf:value "Dulbecco's modified eagle medium (DMEM)" .
  ?reagents ro:has_part ?reagentNameUri3 .
  ?reagentNameUri3 rdf:value "Phosphate buffered saline (PBS)" .
}

11. Retrieve all the protocols that contains Mouse as a Sample

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX p-plan: <http://purl.org/net/p-plan#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?title ?name
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?specimens .
  ?specimens a sp:SpecimenList .
  ?specimens ro:has_part ?specimenNameUri .
  ?specimenNameUri rdf:value ?name .
  ?specimen sp:hasName ?specimenNameUri .
  ?specimen owl:sameAs <http://dbpedia.org/resource/Mouse> .
}

12. Retrieve all the protocols that use the software “ImageJ” along wiht its homepage (http://rsb.info.nih.gov/ij/download.html).

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX p-plan: <http://purl.org/net/p-plan#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dbo: <http://dbpedia.org/ontology/>

SELECT ?title  ?download
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?softwareList .
  ?softwareList a sp:SoftwareList .
  ?softwareList ro:has_part ?softwareNameUri .
  ?software sp:hasName ?softwareNameUri .
  ?softwareNameUri rdf:value "ImageJ software" .
  ?software foaf:homepage ?download .
}

13. Retrieve all the reagents manufactured by Sigma-Aldrich in protocol “Isolation of Lung Infiltrating Cell in Mice”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX obi: <http://purl.obolibrary.org/obo/OBI_>

SELECT ?reagentName
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Isolation of Lung Infiltrating Cell in Mice" .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagent sp:hasName ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  ?reagent obi:0000304 ?manufacturer .
  ?manufacturer sp:hasName ?manufacturerNameUri .
  ?manufacturerNameUri rdf:value "Sigma-Aldrich" .
}

14. Retrieve all the diseases caused by the reagents in the protocol “Extraction of total RNA from fresh/frozen tissue (FT)”

Makes use of external resources, federated query. If federated resources dont respond then this query will give an error msg. Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?reagentName ?reagentSame ?diseaseLabel
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Extraction of total RNA from fresh/frozen tissue (FT)" .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  ?reagent sp:hasName ?reagentNameUri .
  ?reagent owl:sameAs ?reagentSame .
  
  SERVICE <http://sparql.bioontology.org/ontologies/sparql/?apikey=INSERT YOUR API KEY HERE> {
    ?reagentSame <http://purl.bioontology.org/ontology/SNOMEDCT/causative_agent_of> ?diseaseUri.
    ?diseaseUri <http://www.w3.org/2004/02/skos/core#prefLabel> ?diseaseLabel .
  }
}

15. Retrieve all the protocols with “Schizosaccharomyces pombe” in their samples lists

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#> 
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?title
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?specimens .
  ?specimens a sp:SpecimenList .
  ?specimens ro:has_part ?specimenNameUri .
  ?specimenNameUri rdf:value "Schizosaccharomyces pombe" .
}

16. Retrieve the protocols that include 2 or more procedures

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?title
{
    ?experimentalProtocol sp:hasTitle ?titleUri .
    ?titleUri rdf:value ?title .
    ?experimentalProtocolExecution sp:isDocumentedIn ?experimentalProtocol .
    ?experimentalProtocolExecution sp:hasProcedure ?procedure .
    
} GROUP BY ?title HAVING (COUNT(?procedure) > 1)

17. Retrieve the critical steps included in the protocol titled “[Bio101] Subcutaneous Injection of Tumor Cells”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?subprocedureDesc ?criticalStepDescription
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "[Bio101] Subcutaneous Injection of Tumor Cells" .
  ?protocolExecution sp:isDocumentedIn ?protocol .
  ?protocolExecution sp:hasProcedure ?procedure .
  ?procedure sp:hasSubprocedure ?subprocedure .
  ?subprocedure sp:hasAlertMessage ?criticalStep .
  ?subprocedure sp:hasDescription ?subprocedureDescUri .
  ?subprocedureDescUri rdf:value ?subprocedureDesc .
  ?criticalStep a sp:CriticalStep .
  ?criticalStep rdf:value ?criticalStepDescription .
}

18. Retrieve the advantages and limitations of the protocol titled “Defining transcribed regions using RNA-seq”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?advantage ?limitation
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Defining transcribed regions using RNA-seq" .
  ?protocol sp:hasAdvantage ?advantageUri .
  ?protocol sp:hasLimitation ?limitationUri .
  ?advantageUri rdf:value ?advantage .
  ?limitationUri rdf:value ?limitation .
  
}

19. Retrieve the recipe list of the protocol titled “Defining transcribed regions using RNA-seq”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>

SELECT ?recipeName
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Defining transcribed regions using RNA-seq" .
  ?protocol sp:hasExperimentalInput ?recipes .
  ?recipes a sp:RecipeList .
  ?recipes ro:has_part ?recipeNameUri .
  ?recipeNameUri rdf:value ?recipeName .
}

20. For the protocol titled “Defining transcribed regions using RNA-seq”, give me the steps that include cautions as alert message and the materials participating in such step

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?subprocedureDesc ?cautionDescription
       (group_concat(?reagentName; separator=" , ") as ?reagentsNames)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Defining transcribed regions using RNA-seq" .
  ?protocolExecution sp:isDocumentedIn ?protocol .
  ?protocolExecution sp:hasProcedure ?procedure .
  ?procedure sp:hasSubprocedure ?subprocedure .
  ?subprocedure sp:hasAlertMessage ?caution .
  ?subprocedure sp:hasDescription ?subprocedureDescUri .
  ?subprocedureDescUri rdf:value ?subprocedureDesc .
  ?caution a <http://www.owl-ontologies.com/Ontology1184060740.owl#Class_122> .
  ?caution rdf:value ?cautionDescription .
  ?reagentNameUri <http://purl.obolibrary.org/obo/RO_0000056> ?subprocedure .
  ?reagentNameUri rdf:value ?reagentName .
} GROUP BY ?subprocedureDesc ?cautionDescription

21. Retrieve the provenance of the protocol titled “Scratch Wound Healing Assay”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?provenance
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value "Scratch Wound Healing Assay"  .
  ?protocol sp:hasProvenance ?provenanceUri .
  ?provenanceUri rdf:value ?provenance .
}

22. Retrieve the specimen names that could be tested in the protocols titled “A simplified universal genomic DNA extraction protocol suitable for PCR” and “RNA Isolation from Synechocystis”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>

SELECT ?title
(group_concat(distinct(?specimenName); separator=" , ") as ?specimenNames)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?specimens .
  ?specimens a sp:SpecimenList .
  ?specimens ro:has_part ?specimenNameUri .
  ?specimenNameUri rdf:value ?specimenName .
  FILTER(?title = "A simplified universal genomic DNA extraction protocol suitable for PCR" || ?title = "RNA Isolation from Synechocystis")
} GROUP BY ?title

23. Retrieve the protocols and the list of reagents for documents authored by Yanling Chen.

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX IAO: <http://purl.obolibrary.org/obo/IAO_>

SELECT ?title (group_concat(distinct(?reagentName);separator=" | ") as ?reagentNames)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  
  ?protocol ro:has_part ?authors .
  ?authors a IAO:0000321 .
  ?authors ro:has_part ?authorNameUri .
  ?authorNameUri rdf:value "Yanling Chen" .
} GROUP BY ?title

24. Retrieve the protocols authored by Cristian Olaya and Wilmer Cuellar using Cassava (NCBITAXON:3983) as a sample

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX IAO: <http://purl.obolibrary.org/obo/IAO_>

SELECT ?title (group_concat(distinct(?reagentName);separator=" | ") as ?protocolReagents)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?samples .
  ?samples a sp:SpecimenList.
  ?samples ro:has_part ?sampleNameUri .
  ?sample sp:hasName ?sampleNameUri .
  ?sample owl:sameAs <http://purl.bioontology.org/ontology/NCBITAXON/3983> .
  
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  
  ?protocol ro:has_part ?authors .
  ?authors a IAO:0000321 .
  ?authors ro:has_part ?authorNameUri1 .
  ?authorNameUri1 rdf:value "Cristian Olaya" .
  ?authors ro:has_part ?authorNameUri2 .
  ?authorNameUri2 rdf:value "Wilmer Cuellar" .
} GROUP BY ?title

25. Retrieve the common reagents across the protocols “[Bio101] Subcutaneous Injection of Tumor Cells” and “Scratch Wound Healing Assay”

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX IAO: <http://purl.obolibrary.org/obo/IAO_>

SELECT ?commonReagentName
WHERE {
  ?protocol1 sp:hasTitle ?title_uri1 .
  ?title_uri1 rdf:value "[Bio101] Subcutaneous Injection of Tumor Cells" .
  ?protocol1 sp:hasExperimentalInput ?reagents1 .
  ?reagents1 a sp:ReagentList .
  ?reagents1 ro:has_part ?reagentNameUri1 .
  ?reagentNameUri1 rdf:value ?commonReagentName .
 
  ?protocol2 sp:hasTitle ?title_uri2 .
  ?title_uri2 rdf:value "Scratch Wound Healing Assay" .
  ?protocol2 sp:hasExperimentalInput ?reagents2 .
  ?reagents2 a sp:ReagentList .
  ?reagents2 ro:has_part ?reagentNameUri2 .
  ?reagentNameUri2 rdf:value ?commonReagentName .
}

26. Retrieve the protocols in which Bromophenol blue is used and tell me about the application of Bromophenol blue

If federated resources dont respond then this query will give an error msg. This query requieres an API key, see “INSERT YOUR API KEY HERE” Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>

SELECT ?reagentName ?desc (group_concat(?title; separator=" | ") as ?protocols)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  ?reagent sp:hasName ?reagentNameUri .
  ?reagent owl:sameAs <http://purl.obolibrary.org/obo/CHEBI_59424> .
  
  SERVICE <http://sparql.bioontology.org/ontologies/sparql/?apikey=INSERT YOUR BIOPORTAL APIKEY HERE> {
           <http://purl.obolibrary.org/obo/CHEBI_59424> <http://purl.obolibrary.org/obo/def> ?desc .
  }
} GROUP BY ?reagentName ?desc

27. Retrieve the protocols and the list of reagents for documents authored by Yoshimi Umemura

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX IAO: <http://purl.obolibrary.org/obo/IAO_>

SELECT ?title (group_concat(distinct(?reagentName);separator=" | ") as ?reagentNames)
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  
  ?protocol sp:hasExperimentalInput ?reagents .
  ?reagents a sp:ReagentList .
  ?reagents ro:has_part ?reagentNameUri .
  ?reagentNameUri rdf:value ?reagentName .
  
  ?protocol ro:has_part ?authors .
  ?authors a IAO:0000321 .
  ?authors ro:has_part ?authorNameUri .
  ?authorNameUri rdf:value "Yoshimi Umemura" .
} GROUP BY ?title

28. Retrieve the protocols authored by Yoshimi Umemura and Beata Dedicova using rice leaves as sample

Execute it in the endpoint

PREFIX sp: <http://purl.org/net/SMARTprotocol#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX ro: <http://www.obofoundry.org/ro/ro.owl#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX IAO: <http://purl.obolibrary.org/obo/IAO_>

SELECT ?title 
WHERE {
  ?protocol sp:hasTitle ?title_uri .
  ?title_uri rdf:value ?title .
  
  ?protocol sp:hasExperimentalInput ?samples .
  ?samples a sp:SpecimenList.
  ?samples ro:has_part ?sampleNameUri .
  ?sample sp:hasName ?sampleNameUri .
  ?sample owl:sameAs <http://dbpedia.org/page/Rice> .
  
  ?protocol ro:has_part ?authors .
  ?authors a IAO:0000321 .
  ?authors ro:has_part ?authorNameUri .
  ?authorNameUri rdf:value "Yoshimi Umemura" .
}